The simplest way to make SDO videos is by using [jHelioviewer](https://www.jhelioviewer.org/).
If you want to make a video with IDL, we show you below 2 examples on how to generate the images for your video.
To make the actual video from these images, you then can use the IDL command `XINTERANIMATE` or any video encoder of your choice (for example [mencoder](http://www.mplayerhq.hu) or [ffmpeg](https://ffmpeg.org/))
# Prerequisites
To access and work with SDO data within IDL, you need Solar Soft to be installed.
The following instruments must be installed and set in you SSW_INSTR variable : *vso, aia, hmi and ontology*.
See the [Solar Soft documentation](http://www.lmsal.com/solarsoft/) if you don't know how.
See also the [tutorial on how to search and download data](./vso_idl.html)
# Example how to make the video frames for an AIA movie
```idl
; Search the data with vso
hlist = vso_search('1-mar-2011 12:00', '1-mar-2011 12:20', sample=120, inst='aia', wave='171')
print, hlist.physobs, hlist.fileid
; Get the files locally
status = vso_get(hlist, pixels=4096, /rice, filenames=files)
help, files
; The directory where you want to write the results
outdir = '.'
; The subfield of the images that you want
subfield_center = [2048, 2048]
subfield_height = 400
subfield_width = 800
FOR i=0, N_ELEMENTS(files)-1 DO BEGIN
; For each file, extract keywords and image
read_sdo, files[i], hdr, img, /UNCOMP_DELETE
; To improve the contrast, you can for example use the Solar Soft aia_intscale procedure
img = aia_intscale(img, exptime=hdr.EXPTIME, wavelnth=hdr.WAVELNTH, bytescale=1)
; Reduce to a subfield
img = img[subfield_center[0]-(subfield_width/2):subfield_center[0]+(subfield_width/2), subfield_center[1]-(subfield_height/2):subfield_center[1]+(subfield_height/2)]
; Write the img array as a png file
pngfile = outdir + '/' + hdr.T_OBS + ".png"
WRITE_PNG, pngfile, img
ENDFOR
```
# Example how to make the video frames for an HMI movie
```idl
; Search the data with vso
hlist = vso_search('1-mar-2011 12:00', '1-mar-2011 12:20', sample=120, inst='hmi')
print, hlist.physobs, hlist.fileid
; Select what you really want
hlist = vso_search('1-mar-2011 12:00', '1-mar-2011 12:20', sample=120, inst='hmi', physobs='los_magnetic_field')
print, hlist.fileid
; Get the files locally
status=vso_get(hlist, pixels=4096, /rice, filenames=files)
help, files
; The directory where you want to write the results
outdir = '.'
; The subfield of the images that you want
subfield_center = [2048, 2048]
subfield_height = 400
subfield_width = 800
; Thresholding of the pixel intensities (to improve the contrast)
threshold = 30
FOR i=0, N_ELEMENTS(files)-1 DO BEGIN
; For each file, extract keywords and image
read_sdo, files[i], hdr, img , /UNCOMP_DELETE
; Reduce to a subfield
img = img[subfield_center[0]-(subfield_width/2):subfield_center[0]+(subfield_width/2), subfield_center[1]-(subfield_height/2):subfield_center[1]+(subfield_height/2)]
; Smooth if you desire
img = SMOOTH(img, 4 , /EDGE_TRUNCATE, MISSING=0, /NAN)
; Change the contrast by thresholding pixel intensities
img = img > (-threshold) < threshold
; Change the values range so that it is between 0 and 255
img = ((img + threshold) / (2 * threshold)) * 255
; Write the img array as a png file
pngfile = outdir + '/' + hdr.T_OBS + ".png"
WRITE_PNG, pngfile, img
ENDFOR
```
